*  JieJie Microelectronics H-Spice Model Library
*  Filename	: JMSL1004BG_H v.20210723.txt
*  Product Name      	: JMSL1004BG (PDFN5x6)
*  Configuration:	: Single N-channel Device
*  Data Sheet Rev.	: 1.1
*  Release Date	: Jul 21, 2021
*  Junction Temp (Tj)	: -40C ~ 150C
******************************************************************************************************
*  This model is designed as a tool to assist end user(s) to evaluate the performance
*  of the particular SGT MOSFET (named above) released by JJMSH(R).  It has been
*  verified for function and timing integrity with the commercially available EDA simulat-
*  ion tools. End-user(s) is/are advised to take the best engineering practice (e.g.
*  bread-boarding, laboratory measurement) for the full evaluation.
*
*  Despite of the best effort on engineering & verification, JieJie Microelectronics Co.,
*  Ltd. ("JJM") does not provide any warranty nor take any liability to the results and
*  their effects whatsoever from the simulation run of this model by the end-user(s).
*  While this model may be updated at appropriate times in the future without prior
*  notice, JJM does not assume the sole responsibility for update. 
*
.subckt JMSL1004BG D G S 
M1 1 2 3 3 NMOS L=1E-006 W=1E-006
RD D 1 0.00225
RS S 3 1E-006
RG G 2 2.35
CGS 3 G 3.7E-9
EGD 12 0 2 1 1
VFB 14 0 0
FFB 2 1 VFB 1
CGD 13 14 1.25E-9
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 3 D DSUB
RR 13 0 1
D1 12 13 DLIM
CDS D 3 POLY 3.2237E-9 -1.73366E-10 1.24052E-11 -4.41263E-13 7.2746E-15 -5.57696E-17 1.62011E-19

.model NMOS NMOS
+LEVEL = 3                     tlev = 1                      tlevc = 0                     
+acm = 3                       VMAX = 1.0752E9               ETA = 1E-4                    
+VTO = 2.4                     TOX = 8E-10                   NSUB = 3.55E15                
+KP = 280                      U0 = 424                      KAPPA = 0.1                   
+GAMMA = 0.05                  PHI = 0.53                    THETA = 0.2                   
+BEX = -1                      TCV = 3E-3                    DELTA = 30.823493             

.model DCGD D
+CJO = 9E-10                   VJ = 44.4329                  M = 3.97                      

.model DSUB D
+IS = 6E-12                    N = 1.058                     RS = 1.7E-3                   
+BV = 108                      tlev = 0                      tlevc = 0                     
+tref = 25                     eg = 1.11                     keg = 1                       
+gap1 = 7.02E-4                gap2 = 1.108E3                xti = 2.5                     
+cta = 0                       ctp = 0                       tcv = 0                       
+tm1 = 0                       tm2 = 0                       tpb = 0                       
+tphp = 0                      trs = 0                       ttt1 = 0                      
+ttt2 = 0                      xtitun = 3                    

.model DLIM D
+IS = 1E-4                     
.ends JMSL1004BG

******************************************************************************************************
*  Copyright (C) 2021 JJM. All rights reserved.
******************************************************************************************************
